#!/bin/csh -f

#set now=`/usr/local/bin/date +%s`

set db=/home/user/.rtcom-eventlogger/el-v1.db
#CREATE TABLE Events (id INTEGER PRIMARY KEY,service_id INTEGER NOT NULL,event_type_id INTEGER NOT NULL,storage_time INTEGER NOT NULL,start_time INTEGER NOT NULL,end_time INTEGER,is_read INTEGER DEFAULT 0,flags INTEGER DEFAULT 0,bytes_sent INTEGER DEFAULT 0,bytes_received INTEGER DEFAULT 0,local_uid TEXT,local_name TEXT,remote_uid TEXT,channel TEXT,free_text TEXT,group_uid TEXT);
#108|3|7|1264640179|1264640186|1264640178|1|0|0|0|ring/tel/ring||+420607830093||STAT:EUROTEL:3715; T=-13,19; V=189,138,39; S=19; I=10; O=0; A=1000|7830093

#select remote_name from Remotes where remote_uid=='+420736165798'
#select * from Events where service_id==3;

#list all 
if ( ${#} == 0 ) then
sqlite3 $db <<! |\
sort -n -t '|' -k 4|\
awk '-F|' '{printf("%3d. %s %s %-15s (%12s) : %s\n",$1,strftime("%8B  %d %H:%M %Y",$4),($3==7?"FROM":"TO  "),$13,$21,$15);}'
select * from Events,Remotes where service_id==3 and Events.remote_uid == Remotes.remote_uid ;
update Events set is_read = 1 where service_id==3;
delete from GroupCache;
!
exit 0
endif

if ( x"$1" == "xdel" ) then
shift
rm -f  /tmp/sms$$.tmp
foreach i ($*)
        echo delete from Events where Id=$i';' >>/tmp/sms$$.tmp
end
echo 'delete from GroupCache;' >>/tmp/sms$$.tmp
sqlite3 $db < /tmp/sms$$.tmp
rm -f  /tmp/sms$$.tmp
exit 0
endif

if ( x"$1" == "xclean" || x"$1" == "xclear"  ) then
sqlite3 $db <<! 
delete from Events where service_id==3;
delete from GroupCache;
!
exit 0
endif

if ( x"$1" == "xcleanall" || x"$1" == "xclearall"  ) then
sqlite3 $db <<!
delete from Events where service_id==1;
delete from Events where service_id==2;
delete from Events where service_id==3;
delete from Remotes;
delete from GroupCache;
!
exit 0
endif


echo Unknown command $1
exit 1